CUA High Resolution UK101 Support Software

Talk about non-Acorn classic computers/hardware/software here (including retro consoles)
Post Reply
User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

CUA High Resolution UK101 Support Software

Post by tinplatepete » Thu Jun 30, 2016 3:11 pm

Hi. Does anyone have the support software for a Computer User Aids High Resolution Board for a UK101, I have acquired a Board and the instructions but no software. The Board would have come with a Demonstration Tape with the support software on it.
Any help would be much appreciated.
Pete
Pete

User avatar
flaxcottage
Posts: 3190
Joined: Thu Dec 13, 2012 8:46 pm
Location: Derbyshire
Contact:

Re: CUA High Resolution UK101 Support Software

Post by flaxcottage » Thu Jun 30, 2016 5:27 pm

The only info I have on that board is a pretty large PDF of instructions and memory locations used. It is too big to post.

Anything else came with the UK101? And does the computer work? What is it's spec? Pray tell all. [-o<

PM sent
- John
Image

User avatar
Pernod
Posts: 1278
Joined: Fri Jun 08, 2012 10:01 pm
Location: Croydon, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Pernod » Thu Jun 30, 2016 5:38 pm

Sounds interesting, can you Dropbox it somewhere?
- Nigel

BBC Model B, ATPL Sidewise, Acorn Speech, 2xWatford Floppy Drives, AMX Mouse, Viglen case, BeebZIF, etc.

User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by tinplatepete » Thu Jun 30, 2016 6:42 pm

Hi John.

I have the large PDF, Actually I think it originally it came from yourself as I found it on stardot org.
Its the Demo Tape or sofware I am looking for.

I’ll tell you more about the UK101 later, this is my second machine, it works and this board came with it.

Pete.
Pete

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Tue Jul 05, 2016 5:48 am

Hi Pete,

I have several programs for the CUA H-Res Graphics Card.
I have also scanned my manual, when converted to a PDF it became 10.6MB in size.
I am pretty sure I have already shared it with *. via Google Drive, but just in case here is the link:
https://drive.google.com/open?id=0B0PX1 ... 3lVbklyYjg

Someone just bought a UK101 in a slightly tatty state on eBay, it included the FIRST CUA board I have seen listed!
http://www.ebay.co.uk/itm/Vintage-Compu ... true&rt=nc
In case no-one has seen one it looks like this:-
https://drive.google.com/open?id=0B0PX1 ... XFVRGpqMUk

The Demo Software is here:
https://drive.google.com/open?id=0B0PX1 ... lZYWDJoaFk

I rewrote this program to play with polygon/polyhedron rotation and scaling, these follow:
https://drive.google.com/open?id=0B0PX1 ... nhjNDhyYWM
https://drive.google.com/open?id=0B0PX1 ... zNnd21GUGc
https://drive.google.com/open?id=0B0PX1 ... VI4dFliQlU
https://drive.google.com/open?id=0B0PX1 ... m5objloVU0

This last file has been modified from one published in PCW July 1980.
https://drive.google.com/open?id=0B0PX1 ... nZwS2t1YUE

None of the above have been tested as I no longer possess the hardware.
If they work I would love to see screenshots and/or YouTube videos of them functioning!
If they don't please tell me which have problems and I will try to correct them.
I may have one or two others programs lost on tapes that have yet to be read, if I find any I will add them to this post.

I am awaiting a CUA Hi-Res mod to the brilliant UK101 Emulator by Tim Baldwin to try them out for myself.

Hope you find these of use,

Terry (Seldon2k)

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Tue Jul 05, 2016 8:32 pm

Hi,

I have just realised that this is probably a better format for the UK101 programs:

The Demo Software

Code: Select all

 10 POKE 515,0:GOSUB1000:S=4:POKE63,0 
 11 FOR V=1 TO 2
 12 X=128:Y=96:FOR XX=0 TO 254 STEP S:YY=0:GOSUB 100:NEXT
 14 XX=254:FOR YY=0 TO 191 STEP S:GOSUB 100:NEXT 
 16 FOR XX=254 TO 0 STEP -S:GOSUB 100:NEXT:XX=0
 18 FOR YY=191 TO 0 STEP -S:GOSUB 100:NEXT
 19 POKE 40944,3:FOR K=1 TO 2000:NEXT:POKE 40944,0:POKE63,1:NEXT:POKE63,0
 20 FOR J=1 TO 3:FOR K=1 TO 1000:NEXT:POKE 40944,J:GOSUB 1000
 21 READ X,Y,XX,YY:FOR K=1 TO 100-(J*33):NEXT:IF X=-1 THEN RESTORE:NEXT:GOTO23
 22 GOSUB 100: GOTO 21
 23 FOR K=1 TO 2000:NEXT:GOSUB 1000
 24 F=1:POKE 40944,0:FOR G=1 TO 100:W=INT(RND(1)*50):XS=INT(RND(1)*(254-W))
 26 YS=INT(RND(1)*(191-W)):X=XS:Y=YS:XX=X+W:YY=Y:GOSUB 100
 28 YY=YS+W:GOSUB 100:XX=XS:GOSUB 100:YY=YS:GOSUB 100:NEXT
 30 FOR K=1 TO 2000:NEXT:GOSUB 1000
 31 FOR J=1 TO 100:X=RND(1)*254:XX=RND(1)*254
 32 Y=RND(1)*191:YY=RND(1)*191:GOSUB 100:NEXT
 34 FOR K=1 TO 2000:NEXT:GOSUB 1000:POKE 11,242
 36 X0=64:Y0=96:RA=64:FOR J=1 TO 2:DR=5:DP=5:DP=DP*3.14159/180
 38 FOR R=0 TO RA STEP DR:FOR P=0 TO 2*3.14159 STEP DP:X=R*COS(P)
 40 Y=R*SIN(P):X=X0+X:Y=Y0+Y:POKE 64,X:POKE 65,Y:X=USR(X)
 41 NEXT:NEXT:X0=254-64:NEXT:FOR K=1 TO 2000:NEXT 
 42 POKE 11,121:F=0:X=64:Y=96:XX=254-64:YY=Y:GOSUB 100
 44 Y=32:XX=X:YY=Y+128:GOSUB 100:X=254-64:XX=X:GOSUB 100
 46 YY=32:Y=32:X=64:GOSUB 100:YY=160:Y=YY:GOSUB 100
 48 Y=32:FOR XX=64 TO 254-64 STEP 3:YY=160:GOSUB 100:NEXT 
 50 X=254-64:Y=160:YY=32:FOR XX=64 TO X STEP 3:GOSUB 100:NEXT
 52 FORK=1 TO 1000:NEXT:FOR G=1 TO 12:POKE 40944,G:FOR L=1 TO 200:NEXT:NEXT
 54 POKE 40944,0:FOR K=1 TO 2000:NEXT:RUN
 99 END
 100 POKE 64,X:POKE 65,Y:POKE 66,XX:POKE 67,YY:X=USR(X)  
 101 IF F=1 THEN X=XX:Y=YY
 102 RETURN
 200 DATA128,10,158,10,128,60,158,60,193,10,193,60
 202 DATA28,10,58,10,28,35,58,35,78,60,108,60,158,10,158,60
 204 DATA178,10,208,10,78,10,78,60,128,10,128,60
 206 DATA58,10,58,35,28,10,28,60,28,70,208,70
 208 DATA143,90,128,140,143,90,158,140,135,115,151,115
 210 DATA178,90,185,140,185,140,193,90,193,90,201,140
 212 DATA201,140,208,90,28,90,58,115,58,115,28,140,28,140
 214 DATA28,90,78,90,108,90,108,90,108,115,93,115,108,140
 216 DATA78,115,108,115,78,90,78,140,28,150,208,150
 218 DATA-1,-1,-1,-1
 1000 POKE11,89:POKE12,16:X=USR(X):POKE11,121:POKE12,16:RETURN
I rewrote this program to play with polygon/polyhedron rotation and scaling, these follow

Code: Select all

0 PRINT CHR$(26)
1 PRINT"CHOICE WEB(1),PARA-PLOT(2),PARA-DRAW(3)"
2 PRINT"INVERT-PARA(4),[WEB+PARA-DRAW+INV-PARA(5)]"
3 INPUT C
4 ON C GOTO 10,50,150,5,6
5 ZZ=1:GOTO 150
6 AL=1:GOTO 10
7 END
10 POKE 515,0:GOSUB 1000:POKE 63,0
20 READ X,Y,XX,YY
25 IF X=-1 THEN RESTORE:GOTO 41
30 GOSUB 100 
40 GOTO 20
41 IF AL=1 THEN 151
42 END
50 POKE 515,0:GOSUB 1000:POKE 63,0
52 POKE 11,242
55 V=64.5:A=1.25:G=9.81:POKE 11,242
60 FOR X=0 TO 254
70 Y=X*TAN(A)-X^2*G*(1+(TAN(A))^2)/(2*V^2)
71 X=INT(X+.5):Y=INT(Y+.5):IF Y<0 THEN Y=0
72 Y=191-Y
80 POKE 64,X:POKE 65,Y:X=USR(X)
90 NEXT X:END
100 POKE 64,X:POKE 65,Y:POKE 66,XX:POKE 67,YY:X=USR(X)
101 IF F=1 THEN X=XX:Y=YY
102 RETURN
150 POKE 515,0:GOSUB 1000:POKE 63,0
151 X=0:Y=0
155 V=64.5:A=1.25:G=9.81:X=0:Y=0
160 FOR XX=0 TO 254
170 YY=XX*TAN(A)-XX^2*G*(1+(TAN(A))^2)/(2*V^2)
171 XX=INT(XX+.5):YY=INT(YY+.5):IF YY<0 THEN YY=0
172 IF ZZ=1 THEN 180
173 YY=191-YY
180 GOSUB 100
185 X=XX:Y=YY
190 NEXT XX
191 IF AL=1 AND ZZ=1 THEN 194
192 IF AL=1 THEN ZZ=1:GOTO 151
194 END
1000 POKE11,89:POKE12,16:X=USR(X):POKE11,121:POKE12,16:RETURN
2000 DATA 0,0,254,191,254,0,0,191,127,0,127,191
2001 DATA 0,96,254,96,64,48,64,144,191,48,191,144
2002 DATA 64,48,191,48,64,143,191,143
2999 DATA -1,-1,-1,-1
10000 POKE11,89:POKE12,16:X=USR(X):RETURN

Code: Select all

 10 GOSUB 1000:POKE 63,0
 15 GOSUB 200
 16 FOR AL=0 TO 360 STEP 10
 17 GOTO 55
 20 INPUT"ROTATION ANGLES";ALPHA,BETA,GAMMA
 30 INPUT"LOCAL SCALING FACTORS";A,B,C
 40 INPUT"TRANSLATIONS";U,V,W
 50 INPUT"RECIPROCAL VIEWPOINT";RZ
 55 BE=10:GA=0:A=10:B=10:C=10:U=0:V=0:W=0:RZ=0
 60 GOSUB 300
 70 GOSUB 500
 80 GOSUB 700
 83 GOSUB 1000
 85 GOSUB 800
 86 NEXT AL
 90 END
 100 POKE64,X:POKE65,Y:POKE66,XX:POKE67,YY:X=USR(X)
 101 IF FF=1 THEN X=XX:Y=YY
 102 RETURN
 200 READ N
 210 DIM OC(N,4),TC(N,4),T(4,4),IC(N,2),SC(N,2)
 220 FOR R=1 TO N:FOR C=1 TO 3:READ OC(R,C)
 230 NEXT C:OC(R,4)=1:NEXT R:RETURN
 300 F=3.141592/180
 310 SA=SIN(ALPHA*F):CA=COS(ALPHA*F):SB=SIN(BETA*F)
 320 CB=COS(BETA*F):SG=SIN(GAMMA*F):CG=COS(GAMMA*F)
 330 T(1,1)=A*CB*CG
 340 T(1,2)=B*CB*SG
 350 T(1,4)=C*SB*RZ
 360 T(2,1)=A*(SA*SB*CG-CA*SG)
 370 T(2,2)=B*(SA*SB*SG+CA*CG)
 380 T(2,4)=-C*SA*CB*RZ
 390 T(3,1)=A*(CA*SB*CG+SA*SG)
 400 T(3,2)=B*(CA*SB*SG-SA*CG)
 410 T(3,4)=-C*CA*CB*RZ
 420 T(4,1)=U:T(4,2)=V:T(4,4)=1-W*RZ
 430 FOR R=1 TO 4:T(R,3)=0:NEXT R
 440 RETURN
 500 FOR R=1 TO N:FOR C=8 TO 4:S=0
 510 FOR J=1 TO 4:S=S+OC(R,J)*T(J,C):NEXT J
 520 TC(R,C)=S:NEXT C:NEXT R:RETURN
 700 REM
 710 P=254:Q=191:YD=50
 720 FOR R=1 TO N
 730 SC(R,1)=INT(TC(R,1)*Q/YD/TC(R,4)+P/2)
 740 SC(R,2)=INT(TC(R,2)*Q/YD/TC(R,4)+Q/2)
 750 NEXT R:RETURN
 800 READ NL:FOR L=1 TO NL
 810 READ P1,P2
 820 X=SC(P1,1):Y=SC(P1,2):XX=SC(P2,1)
 823 YY=SC(P2,2):Y=191-Y:YY=191-YY:GOSUB 100
 830 NEXT L
 840 RESTORE:FORT=1 TO 25:READ T1:NEXT:RETURN
 900 DATA 8,-1,1,1,1,1,1,1,-1,1,-1,-1,1,-1,1,-1
 910 DATA 1,1,-1,1,-1,-1,-1,-1,-1
 950 DATA 12,1,2,2,3,3,4,4,1,1,5,5,6
 960 DATA 6,7,7,8,8,5,2,6,3,7,4,8
 1000 POKE11,89:POKE12,16:X=USR(X):POKE11,121:POKE12,16:RETURN

Code: Select all

 100 INPUT"CHOOSE VIEW POSITION; X,Y,Z";L,M,N
 110 INPUT"LOOKING TOWARDS; X,Y,Z";A,B,C
 115 L=L-A:M=M-B:N=N-C:X1=64:Y1=65:X2=66:Y2=67
 116 MODE=40944:RES=0:COM=63
 117 POKE 11,89:POKE 12,16:POKE MODE,RES:POKE COM,0:X=USR(X)
 150 S=L*L+M*M:R=SQR(S):W=4
 160 T=S+N*N:Q=SQR(T)
 200 FOR X=-10 TO 10
 210 Y=-10:GOSUB600:GOSUB 410
 220 FORY=-9 TO 10:GOSUB 600:GOSUB 400:NEXT:NEXT
 230 FOR Y=-10 TO10
 240 X=-10:GOSUB 600:GOSUB 410
 250 FOR X=-9TO 10:GOSUB600:GOSUB400:NEXT:NEXT
 260 END
 400 W=5
 410 U=X-A:V=Y-B:W=Z-C
 420 O=(T-X*L-Y*M-Z*N)*R
 425 IF O<0.1THEN W=4
 430 G=(400*(Y*L-X*M)*Q/O)+128
 440 H=(500*(Z*s-N*(X*L+Y*M))/O)+96
 460 IFW=5 THEN GOSUB 700:RETURN
 461 IFW=4 THEN GOSUB 800:RETURN
 600 Z=0.05*(Y*y-X*X):RETURN
 700 POKE 11121:POKE 12,16
 701 POKE X1,G:POKE Y1,H:X=USR(X)
 702 W=4:RETURN
 800 POKE X2,G:POKE Y2,H:W=4:RETURN

Code: Select all

 10 Z=60:X=64:Y=65
 20 POKE 11,89:POKE 12,16:X=USR(X):POKE 11,242:POKE 12,16
 25 POKE 40944,4:POKE 63,0
 30 FOR Q=0TO 359
 40 S=Q*2*3.14159360
 50 R=Z*SIN(S*2)
 60 POKE X,R*SIN(S)+64.5:POKE Y,R*COS(S)+48.5
 65 X=USR(X)
 70 NEXT Q
This last file has been modified from one published in PCW July 1980.

Code: Select all

 1 REM THREE-DIMENSIONAL PLOTTER
 2 REM V=113 TO KEEP THE ASPECT-RATIO CORRECT
 10 GOSUB 1000:POKE 63,0:H=254:V=113
 20 X1=H/2:X2=X1*X1:Y1=V/2:Y2=V/4
 40 FOR X=0 TO X1
 50 X4=X*X:M=-Y1
 60 A=SQR(X2-X4)
 70 FOR I=-A TO A STEP V/10
 75 R=SQR(X4+I*I)/X1
 80 F=(R-1)*SIN(R*12)
 90 Y=I/5+F*Y2
 100 IF Y<=M THEN 120
 105 M=Y:Y=Y1-Y
 110 POKE 64,X1-X:POKE 65,Y:X=USR(X)
 111 POKE 64,X1+X:POKE 65,Y:X=USR(X)
 120 NEXT I:NEXT X
 130 END
 140 REM TRY 80 F=EXP(COS(12*R))/3
 141 REM TRY 80 F=COS(18*R)*(1-R)^2
 142 REM TRY 80 F=SIN(R*3)
 143 REM TRY 80 F=(1-R)^4
 144 REM SEE JULY 1980 P.C.W PAGE 80 FOR PICS
 1000 POKE 11,89:POKE 12,16:X=USR(X)
 1001 POKE 11,242:POKE 12,16:RETURN
The board looks like this
CUA Hi-Res Graphics Board (Edited & Cropped).jpg
This board gave me my first twin monitor system in 1982.
I simply took the output from the graphics card to a second TV, later replaced in approx. 1985 with a green screen monitor.
The main display of the UK101 went to my Portable TV to the front of which I had attached a green plastic filter, constructed by me in 1980.
The only other multi-monitor systems I can think of at that time would be an IBM PC (5150) with both MDA and CGA cards,
running the DOS version of AutoCAD.

I have just found some data blocks containing corner data for different solids for one of the above programs.
These all start at line 900, so simply combine them or load them after loading a version of the program missing this data.

Polygon Data

Code: Select all

 900 DATA 4,0,3.6822,0,-1.5,0,-.4375,1.5,0
 910 DATA -.4375,0,0,1.5625
 950 DATA 6,1,2,2,3,3,1,1,4,4,2,4,3

Code: Select all

 900 DATA 5,0,3.6822,0,-1.5,0,-.4375,1.5,0
 910 DATA -.4375,0,0,1.5625,0,-3.6822,0
 950 DATA 9,1,2,2,3,3,1,1,4,4,5,5,2,2,4,4,3,3,5

Code: Select all

 900 DATA 7,0,3.6822,0,-1.5,0,-.4375,1.5,0
 910 DATA -.4375,0,0,1.5625,-1.5,7.3644,-.4375
 920 DATA 1.5,7.3644,-.4375,0,7.3644,1.5625
 950 DATA 12,1,2,2,3,3,1,1,4,4,2,4,3,1,5,5,6
 960 DATA 6,1,1,7,7,6,5,7

Code: Select all

 900 DATA 6,1,0,1,-1,0,1,-1,0,-1,1,0,-1
 910 DATA 0,1,0,0,-1,0
 950 DATA 12,1,2,2,3,3,4,4,1
 960 DATA 5,1,5,2,5,3,5,4
 970 DATA 6,1,6,2,6,3,6,4
I will add the Polyhedron Data in the next post.

Looking forward to some feedback,

Terry (Seldon2k)
Last edited by Seldon2k on Wed Jul 06, 2016 5:45 am, edited 2 times in total.

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Wed Jul 06, 2016 5:41 am

Hi,

Polyhedron Point Data

Code: Select all

 899 REM POINT DEFINITION DATA HERE
 900 DATA 36,2,0,0,1.96962,0,.347296
 901 DATA 1.87939,0,.68404,1.73205,0,1
 902 DATA 1.53209,0,1.28558,1.28558,0,1.53209
 903 DATA 1,0,1.73205,.68404,0,1.87939
 904 DATA .347296,0,1.96962,0,0,2
 905 DATA -.347297,0,1.96962,-.68404,0,1.87939
 906 DATA -1,0,1.73205,-1.28558,0,1.53209
 907 DATA -1.53209,0,1.28558,-1.73205,0,1
 908 DATA -1.87939,0,.68404,-1.96962,0,.347297
 909 DATA -2,0,0,-1.96962,0,-.347297
 910 DATA -1.87939,0,-.68404,-1.73205,0,-1
 911 DATA -1.53209,0,-1.28558,-1.28558,0,-1.53209
 912 DATA -1,0,-1.73205,-.68404,0,-1.87939
 913 DATA -.347297,0,-1.96962,0,0,-2
 914 DATA .347297,0,-1.96962,.684041,0,-1.87939
 915 DATA 1,0,-1.73205,1.28557,0,-1.53209
 916 DATA 1.53209,0,-1.28558,1.73205,0,-1
 917 DATA 1.87939,0,-.684041,1.96962,0,-.347297
 1099 REM JOINING INFORMATION HERE
 1100 DATA 36,1,2,2,3,3,4,4,5,5,6,6,7,7,8,8,9
 1101 DATA 9,10,10,11,11,12,12,13,13,14,14,15
 1102 DATA 15,16,16,17,17,18,18,19,19,20,20,21
 1103 DATA 21,22,22,23,23,24,24,25,25,26,26,27
 1104 DATA 27,28,28,29,29,30,30,31,31,32,32,33
 1105 DATA 33,34,34,35,35,36,36,1

Code: Select all

 899 REM POINT DEFINITION DATA HERE
 900 DATA 37,2,0,0,1.96962,0,.347296
 901 DATA 1.87939,0,.68404,1.73205,0,1
 902 DATA 1.53209,0,1.28558,1.28558,0,1.53209
 903 DATA 1,0,1.73205,.68404,0,1.87939
 904 DATA .347296,0,1.96962,0,0,2
 905 DATA -.347297,0,1.96962,-.68404,0,1.87939
 906 DATA -1,0,1.73205,-1.28558,0,1.53209
 907 DATA -1.53209,0,1.28558,-1.73205,0,1
 908 DATA -1.87939,0,.68404,-1.96962,0,.347297
 909 DATA -2,0,0,-1.96962,0,-.347297
 910 DATA -1.87939,0,-.68404,-1.73205,0,-1
 911 DATA -1.53209,0,-1.28558,-1.28558,0,-1.53209
 912 DATA -1,0,-1.73205,-.68404,0,-1.87939
 913 DATA -.347297,0,-1.96962,0,0,-2
 914 DATA .347297,0,-1.96962,.684041,0,-1.87939
 915 DATA 1,0,-1.73205,1.28557,0,-1.53209
 916 DATA 1.53209,0,-1.28558,1.73205,0,-1
 917 DATA 1.87939,0,-.684041,1.96962,0,-.347297
 918 DATA 0,2,0
 1000 POKE11,89:POKE12,16:X=USR(X):POKE11,121:POKE12,16:RETURN
 1099 REM JOINING INFORMATION HERE
 1100 DATA 72,1,2,2,3,3,4,4,5,5,6,6,7,7,8,8,9
 1101 DATA 9,10,10,11,11,12,12,13,13,14,14,15
 1102 DATA 15,16,16,17,17,18,18,19,19,20,20,21
 1103 DATA 21,22,22,23,23,24,24,25,25,26,26,27
 1104 DATA 27,28,28,29,29,30,30,31,31,32,32,33
 1105 DATA 33,34,34,35,35,36,36,1
 1110 DATA 1,37,2,37,3,37,4,37,5,37,6,37,7,37
 1111 DATA 8,37,9,37,10,37,11,37,12,37,13,37
 1112 DATA 14,37,15,37,16,37,17,37,18,37,19,37
 1113 DATA 20,37,21,37,22,37,23,37,24,37,25,37
 1114 DATA 26,37,27,37,28,37,29,37,30,37,31,37
 1115 DATA 32,37,33,37,34,37,35,37,36,37

Code: Select all

 899 REM POINT DEFINITION DATA HERE
 900 DATA 38,2,0,0,1.96962,0,.347296
 901 DATA 1.87939,0,.68404,1.73205,0,1
 902 DATA 1.53209,0,1.28558,1.28558,0,1.53209
 903 DATA 1,0,1.73205,.68404,0,1.87939
 904 DATA .347296,0,1.96962,0,0,2
 905 DATA -.347297,0,1.96962,-.68404,0,1.87939
 906 DATA -1,0,1.73205,-1.28558,0,1.53209
 907 DATA -1.53209,0,1.28558,-1.73205,0,1
 908 DATA -1.87939,0,.68404,-1.96962,0,.347297
 909 DATA -2,0,0,-1.96962,0,-.347297
 910 DATA -1.87939,0,-.68404,-1.73205,0,-1
 911 DATA -1.53209,0,-1.28558,-1.28558,0,-1.53209
 912 DATA -1,0,-1.73205,-.68404,0,-1.87939
 913 DATA -.347297,0,-1.96962,0,0,-2
 914 DATA .347297,0,-1.96962,.684041,0,-1.87939
 915 DATA 1,0,-1.73205,1.28557,0,-1.53209
 916 DATA 1.53209,0,-1.28558,1.73205,0,-1
 917 DATA 1.87939,0,-.684041,1.96962,0,-.347297
 918 DATA 0,2,0,0,-2,0
 1000 POKE11,89:POKE12,16:X=USR(X):POKE11,121:POKE12,16:RETURN
 1099 REM JOINING INFORMATION HERE
 1100 DATA 108,1,2,2,3,3,4,4,5,5,6,6,7,7,8,8,9
 1101 DATA 9,10,10,11,11,12,12,13,13,14,14,15
 1102 DATA 15,16,16,17,17,18,18,19,19,20,20,21
 1103 DATA 21,22,22,23,23,24,24,25,25,26,26,27
 1104 DATA 27,28,28,29,29,30,30,31,31,32,32,33
 1105 DATA 33,34,34,35,35,36,36,1
 1110 DATA 1,37,2,37,3,37,4,37,5,37,6,37,7,37
 1111 DATA 8,37,9,37,10,37,11,37,12,37,13,37
 1112 DATA 14,37,15,37,16,37,17,37,18,37,19,37
 1113 DATA 20,37,21,37,22,37,23,37,24,37,25,37
 1114 DATA 26,37,27,37,28,37,29,37,30,37,31,37
 1115 DATA 32,37,33,37,34,37,35,37,36,37
 1120 DATA 1,38,2,38,3,38,4,38,5,38,6,38,7,38
 1121 DATA 8,38,9,38,10,38,11,38,12,38,13,38
 1122 DATA 14,38,15,38,16,38,17,38,18,38,19,38
 1123 DATA 20,38,21,38,22,38,23,38,24,38,25,38
 1124 DATA 26,38,27,38,28,38,29,38,30,38,31,38
 1125 DATA 32,38,33,38,34,38,35,38,36,38
That took a while as I had some duplicate files.

Terry, (Seldon2k)

User avatar
hoglet
Posts: 7446
Joined: Sat Oct 13, 2012 6:21 pm
Location: Bristol
Contact:

Re: CUA High Resolution UK101 Support Software

Post by hoglet » Wed Jul 06, 2016 6:38 am

Any chance of a screen shot so we can see what that wonderful machine is capable of?

Is the resolution 256x192, same as the Atom?

In fact, if I squint hard enough at the photo is that a 6847 I can see?

Dave

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Wed Jul 06, 2016 1:29 pm

Hi Dave,

Yes, the highest resolution is 256 x 192. The 6kB of RAM starts at 8000H
so the board makes a UK101 graphically equivalent to an Acorn Atom.

This is all covered on page 1 of the manual that is available via the first link at the top of the post.
I too await some screenshots and or videos of this board in use.

Terry, (Seldon2k)

User avatar
hoglet
Posts: 7446
Joined: Sat Oct 13, 2012 6:21 pm
Location: Bristol
Contact:

Re: CUA High Resolution UK101 Support Software

Post by hoglet » Wed Jul 06, 2016 2:10 pm

Seldon2k wrote: Yes, the highest resolution is 256 x 192. The 6kB of RAM starts at 8000H
so the board makes a UK101 graphically equivalent to an Acorn Atom.
Thanks Terry, I somehow missed that link.

Dave

User avatar
Pernod
Posts: 1278
Joined: Fri Jun 08, 2012 10:01 pm
Location: Croydon, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Pernod » Wed Jul 06, 2016 3:30 pm

Seldon2k wrote:I am awaiting a CUA Hi-Res mod to the brilliant UK101 Emulator by Tim Baldwin to try them out for myself.
Is Tim aware of this? I see he's been active on the emulator in the past few days.

I also intend to add it to MAME, but the manual is not too descriptive about the schematics, so may wait for Tim to work it out first ;)
- Nigel

BBC Model B, ATPL Sidewise, Acorn Speech, 2xWatford Floppy Drives, AMX Mouse, Viglen case, BeebZIF, etc.

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Wed Jul 06, 2016 8:16 pm

Hi,

I mentioned it to Tim over two and a half years ago. viewtopic.php?f=45&t=6108&start=60
Actually that was a reminder, I had emailed him about it during the previous year.
The problem at the time as a lack of enough information on the board.
I didn't mean to imply he was currently working on it, I just meant that he was aware.

Although it would be very nice to have a full circuit diagram, it is not really needed.
We know the address of the chip select line for the 6847 and the base address of the 6kB of static RAM.
Also this has already been solved in the Acorn ATOM Emulator, also I believe two members of *. were discussing
ATOM Hardware and how to represent it in an FPGA recently.
If I find the reference I will post a link to it here.

Terry, (Seldon2k)
Last edited by Seldon2k on Wed Jul 06, 2016 9:48 pm, edited 1 time in total.

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Wed Jul 06, 2016 8:31 pm

Hi,

I have just reviewed the photo of the Graphics Board and if it were scanned at high resolution it could be reverse engineered.
Unfortunately, when I owned this hardware I had no access to a scanner or a digital camera.

I wonder if Pete could scan it on both sides, after carefully disconnecting it from the 40 way expansion cable.

Terry, (Seldon2k)

baldwint
Posts: 14
Joined: Mon Sep 30, 2013 6:31 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by baldwint » Sat Jul 09, 2016 8:23 pm

Terry sent me details of the HiRes board quite a while back and I did promise take a look at adding it to my emulation. Originally I thought it might be fairly easy, but turns out I was bit bit optimistic! Reading throuhg the specs I decided it wasn't going to be quite so easy after all and it has sat on the back-burner ever since.

One day, perhaps I'll have another go, but TBH, don't hold your breath ... :-)

Tim.

ps Terry - thanks for the PM - can't seem to reply directly to you though.

User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by tinplatepete » Thu Nov 10, 2016 6:43 pm

Hi All.

I have not been around for a while what with family commitments etc. I have been reading through the thread and it appears I have a lot of catching up to do.

Terry thanks for files that you posted I can’t wait to get the card up and running to try them out and ill get some screen shots.

As soon as I get a chance I will take some hi res pictures of the card and post them on this thread.
Pete

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Sun Oct 29, 2017 4:43 pm

Pete,

It has been a YEAR since that last post.
I hope you managed to get the CUA board working with the software supplied above.
Please give an update on your progress.

Yours impatiently,
Terry (Seldon2k)

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Thu Apr 12, 2018 1:08 am

Pete,

Here is the Demo program for the CUA board in 'Tidy' format.
I 'may' if I find the time, and I am crazy enough, add comments to clarify the code.

Code: Select all

 10 POKE 515, 0 : GOSUB 1000 : S = 4 : POKE 63, 0

 11 FOR V = 1 TO 2
 12	X = 128 : Y = 96
 11	FOR XX = 0 TO 254 STEP S
 12		YY=0
 13		GOSUB 200
 14	NEXT XX
 15	XX = 254
 16	FOR YY = 0 TO 191 STEP S
 17		GOSUB 200
 18	NEXT YY
 19	FOR XX = 254 TO 0 STEP -S
 20		GOSUB 200
 21	NEXT XX
 22	XX = 0
 23	FOR YY = 191 TO 0 STEP -S
 24		GOSUB 200
 25	NEXT YY
 26	POKE 40944, 3
 27	FOR K=1 TO 2000 : NEXT K
 28	POKE 40944,0
 29	POKE 63, 1
 30 NEXT V

 31 POKE 63, 0

 32 FOR J=1 TO 3
 33	FOR K=1 TO 1000 : NEXT K
 34	POKE 40944, J
 35	GOSUB 2000
 36	READ X, Y,  XX, YY
 37	FOR K = 1 TO 100 - (J * 33)
 38	NEXT K
 39	IF X = - 1 THEN RESTORE
 40 NEXT J

 41 GOTO 44
 42 GOSUB 200
 43 GOTO 36

 44 FOR K=1 TO 2000 : NEXT K
 45 GOSUB 2000

 46 F=1
 47 POKE 40944, 0

 48 FOR G = 1 TO 100
 49	W = INT(RND(1) * 50)
 50	XS = INT(RND(1) * (254 - W))
 51	YS = INT(RND(1) * (191 - W))
 52	X = XS : Y = YS : XX = X + W : YY = Y
 53	GOSUB 200
 54	YY = YS + W
 55	GOSUB 200
 56	XX = XS
 57	GOSUB 200
 58	YY = YS
 59	GOSUB 200
 60 NEXT G

 61 FOR K=1 TO 2000 : NEXT

 62 GOSUB 2000

 63 FOR J=1 TO 100
 64	X    = RND(1) * 254
 65	XX = RND(1) * 254
 66	Y   = RND(1) * 191
 67	YY = RND(1) * 191
 68	GOSUB 200
 69 NEXT J

 70 FOR K=1 TO 2000 : NEXT K

 71 GOSUB 2000

 71 POKE 11,242
 72 X0 = 64 : Y0 = 96 : RA = 64
 73 FOR J=1 TO 2
 74 	DR=5 : DP=5 : DP=DP * 3.14159/180
 75		FOR R=0 TO RA STEP DR
 76			FOR P=0 TO 2 * 3.14159 STEP DP
 77				X = R * COS(P)
 78				Y = R * SIN(P)
 79				X = X0 + X
 80				Y = Y0 + Y
 81				POKE 64, X : POKE 65, Y : X=USR(X)
 82			 NEXT P
 83		NEXT R
 84 X0 = 254-64
 85 NEXT J

 86 FOR K=1 TO 2000 : NEXT K

 87 POKE 11, 121
 88 F = 0 : X = 64 : Y=96 : XX = 254 - 64 :YY = Y : GOSUB 200
 89 Y = 32 : XX = X : YY = Y + 128 :GOSUB 200
 90 X = 254 - 64 : XX = X : GOSUB 200
 91 YY = 32 : Y = 32 : X = 64 : GOSUB 200
 92 YY = 160 : Y = YY : GOSUB 200

 93 Y = 32
 94 FOR XX = 64 TO 254 - 64 STEP 3
 95	YY = 160
 96	GOSUB 200
 97 NEXT XX

 98 X = 254 - 64 : Y = 160 : YY = 32
 99 FOR XX = 64 TO X STEP 3
100	GOSUB 200
101 NEXT

102 FOR K=1 TO 1000 : NEXT K

103 FOR G=1 TO 12
104	 POKE 40944,G
105	 FOR L=1 TO 200 : NEXT L
106 NEXT G

107 POKE 40944, 0
108 FOR K=1 TO 2000 : NEXT K
109 RUN
199 END

200 POKE 64,X : POKE 65,Y : POKE 66,XX : POKE 67,YY : X=USR(X) 
201 IF F=1 THEN X=XX : Y=YY
202 RETURN

300 DATA 128, 10, 158, 10, 128, 60, 158, 60, 193, 10, 193, 60
302 DATA 28, 10, 58, 10, 28, 35, 58, 35, 78, 60, 108, 60, 158, 10, 158, 60
304 DATA 178, 10, 208, 10, 78, 10, 78, 60, 128, 10, 128, 60
306 DATA 58, 10, 58, 35, 28, 10, 28, 60, 28, 70, 208, 70
308 DATA 143, 90, 128, 140, 143, 90, 158, 140, 135, 115, 151, 115
310 DATA 178, 90, 185, 140, 185, 140, 193, 90, 193, 90, 201, 140
312 DATA 201, 140, 208, 90, 28, 90, 58, 115, 58, 115, 28, 140, 28, 140
314 DATA 28, 90, 78, 90, 108, 90, 108, 90, 108, 115, 93, 115, 108, 140
316 DATA 78, 115, 108, 115, 78, 90, 78, 140, 28, 150, 208, 150
318 DATA -1, -1, -1, -1

1000 POKE 11, 89 : POKE 12, 16 : X=USR(X) : POKE 11, 121 : POKE 12, 16 : RETURN
Pete here is the RAM Scanner program to help find the CUA graphics board, if it has been relocated:

Code: Select all

 10 REM RAM Scanner to find the CUA Board
 20 REM Author - Terry, (Seldon2k)
 25 REM Date   - 12th April 2018
 30 INPUT"Enter RAM Size (kB) : ";START
 40 FOR RAM = (START*1024)+1 TO 40959
 50 POKE RAM,85
 60 RT1=PEEK(RAM)
 70 POKE RAM,170
 80 RT2=PEEK(RAM)
 85 IF (RT1=85 AND RT2=170) THEN 500
 90 NEXT RAM
 100 PRINT"No RAM has been found!"
 110 END
 500 PRINT"RAM has been found at : ";RAM
 510 END
 
Regards,
Terry, (Seldon2k)

User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by tinplatepete » Sat Apr 14, 2018 3:37 pm

These are the modifications that have been done to the card, I am not sure if they are original or some attempt to re address it.
I will post some more pictures of the card soon.
Attachments
20171207_125300.jpg
20171207_115419.jpg
20171207_115329.jpg
20171207_115322.jpg
20171207_115315.jpg
20171207_115305_001.jpg
Pete

User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by tinplatepete » Sat Apr 14, 2018 4:26 pm

These are not Hi Res pictures but give an idea of the track layout of this card, I will post some better pictures as soon as I get a chance.
Attachments
20180414_170433a.jpg
20180414_170403a.jpg
Pete

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Sun Apr 15, 2018 1:38 am

Hi Pete,

Yes, thanks for those images it is possible to make a start on Rev-Enging the circuit.
I have rotated and reposted them below along with the component layout diagram from the manual.
CUA (Top).jpg
Component Layout.jpg
CUA (Bottom).jpg
I look forward to the Hi-Res versions, please try and take two of the component side, one slightly to the left of vertical
and the other slightly to the right. This will allow me to see where the tracks terminate.
Either at the pin of an IC or between two adjacent pins.

Don't forget to try my Memory Scanner program to see if it finds the board.
Also, note that I have just updated the layout diagram as R7 was mislabeled as R1.


Regards,
Terry (Seldon2k)
Last edited by Seldon2k on Fri Apr 27, 2018 10:24 pm, edited 1 time in total.

User avatar
tinplatepete
Posts: 28
Joined: Tue Oct 06, 2015 9:50 pm
Contact:

Re: CUA High Resolution UK101 Support Software

Post by tinplatepete » Sun Apr 15, 2018 2:13 pm

I took these today, hopefully they will be of use.
Attachments
IMG_0098.JPG
IMG_0097.JPG
IMG_0096.JPG
IMG_0095.JPG
IMG_0094.JPG
IMG_0093.JPG
IMG_0092.JPG
IMG_0091.JPG
IMG_0090.JPG
Pete

User avatar
Seldon2k
Posts: 110
Joined: Sun Dec 08, 2013 3:19 am
Location: Redditch, UK
Contact:

Re: CUA High Resolution UK101 Support Software

Post by Seldon2k » Fri Apr 27, 2018 10:33 pm

Hi Peter,

I have finally started to do something with the Rev-Eng project.
Thanks to tinplatepete we I now have a complete BOM which is attached below.
Component BOM.odt
(12.06 KiB) Downloaded 7 times
Component BOM.doc
(13 KiB) Downloaded 8 times
I have also created a set of images of the IC pinouts to aid with the reverse-engineering process.
I have attached an updated zip of these below for anyone interested.
IC Pinouts.zip
(287.79 KiB) Downloaded 8 times
Regards,
Terry, (Seldon2k)
Last edited by Seldon2k on Mon Apr 30, 2018 4:34 am, edited 3 times in total.

Post Reply