Any short type-ins for unattended Beebs?

bbc/electron apps, languages, utils, educational progs, demos + more
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

The Persian rug program from the Beeb user guide:

Code: Select all

0MODE1:D%=4:VDU19,2,RND(3)+1,0,0,0,19,3,RND(3)+4,0,0,0,29,640;512;:J%=0:FORK%=400TO280STEP-40:REPEATA%=RND(3):UNTILA%<>J%:J%=A%:GCOL3,J%:FORI%=-K%TOK%STEPD%:MOVEK%,I%:DRAW-K%,-I%:MOVEI%,-K%:DRAW-I%,K%:NEXT,:TIME=0:REPEATUNTILTIME>500:RUN
Run in JSBeeb:
:idea:
User avatar
AndyF
Posts: 1276
Joined: Sat Feb 23, 2008 10:16 pm
Location: Derby
Contact:

Re: Any short type-ins for unattended Beebs?

Post by AndyF »

Some quite similar ( and shameful quality :oops: ) small randomness:
patterns.ssd
(3 KiB) Downloaded 40 times
Consists of:

Blocks / Characters / Bricks / Letters / Squares / Numbers / Solid

Preview combi-pics:
solid.png
solid.png (1.74 KiB) Viewed 2378 times
mixed.png
:oops:

I don't think there was a great deal of point in having a 'numbers' and 'letters' and 'characters' as separate files actually, oh well. Having said that I did try in Mode7 to have random text characters and teletext graphic blocks but despite my efforts it always added a space after, even when forcing a backspace I could not get it to behave properly. I must revisit that, hence why the above are all Mode2...
Last edited by AndyF on Thu Apr 11, 2019 4:32 pm, edited 2 times in total.
Andy

* NEW * The Jetset Willy and Manic Miner community :)

Adventure games ported across to the BBC (in progress) as soon as I can find some time!
User avatar
AndyF
Posts: 1276
Joined: Sat Feb 23, 2008 10:16 pm
Location: Derby
Contact:

Re: Any short type-ins for unattended Beebs?

Post by AndyF »

You know it might of been more sensible thinking about this (aside from just pressing BREAK and not saving the Basic!) to either of put them all into one piece of Basic where either one choice would be selected at random and then perhaps cycled every few minutes (so ti was completely unattended) or have a cheapy menu choice of which pattern/effect to use.

By the latter I don't mean a 'Menu' Basic which loaded the appropriate file, merely a choice in the single file itself. Anyway does not matter too much I guess.

Andy awaits other's new "short type-in's" in much anticipation! :D
Andy

* NEW * The Jetset Willy and Manic Miner community :)

Adventure games ported across to the BBC (in progress) as soon as I can find some time!
User avatar
BigEd
Posts: 3735
Joined: Sun Jan 24, 2010 10:24 am
Location: West Country
Contact:

Re: Any short type-ins for unattended Beebs?

Post by BigEd »

That's great!
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

This is a bit of a long type-in (but it's a variation on an earlier theme in this thread):

Code: Select all

REM Set up a pseudo-array of integer values 0..1278
 10 MODE7:PRINTTAB(11,10)"Preparing... ";:C%=0:B%=0:O%=0:J%=0:A%=0:DIM S% 2558:FORI%=0TO1278:S%?(2*I%)=I%MOD256:S%?(2*I%+1)=I%DIV256:NEXT:VDU23;8202;0;0;0;
REM Shuffle the values to create a random order for later 
 20 FORI%=0TO1278:R%=RND(1279)-1:T%=(S%?(2*R%))+256*(S%?(2*R%+1)):S%?(2*R%)=S%?(2*I%):S%?(2*R%+1)=S%?(2*I%+1):S%?(2*I%)=T%MOD256:S%?(2*I%+1)=T%DIV256:PRINTTAB(24,10);1278-I%;"   ";:NEXT
REM "Screensaver" pattern begins
REM Define two colours and two UDG characters
 30 MODE1:VDU23;8202;0;0;0;19,3,2;0;0;0;19,2,6;0;0;0;23,128,1,2,4,8,16,32,64,128,23,129,128,64,32,16,8,4,2,1
REM Main loop
 40 REPEAT
REM Colour 3 to print pattern, colour 0 to erase
 50  C%=C%EOR1:IFC%=1COLOUR3ELSECOLOUR0
REM Fill in bottom-right corner "manually"
 60  IFC%=1ANDB%=0VDU31,39,31,127+RND(2),31,0,0,11
 70  B%=0
REM Count upwards when printing pattern
 80  IF C%=1 A%=J%:Z%=1278:P%=1
 REM Count down when erasing pattern
 90  IF C%=0 A%=1278:Z%=0:P%=-1
REM Loop to print (or erase) pattern
100  FORI%=A%TOZ%STEPP%
REM Calculate which value to pick from shuffled sequence
110   U%=(I%+O%)MOD1279
120   R%=(S%?(2*U%))+256*(S%?(2*U%+1))
REM Convert value to X,Y text-coordinates
130   Y%=R%DIV40:X%=R%MOD40
140   VDU31,X%,Y%
REM Sometimes switch colours when printing pattern
150   IFC%=1ANDRND(1280)>1100COLOUR2:VDU127+RND(2):COLOUR3ELSEVDU127+RND(2)
REM Sometimes erase part of pattern rather than entire pattern
160   IFC%=0ANDRND(1280)>1278J%=I%:I%=-1:B%=1
170  NEXT
REM If entire pattern has been erased, CLS to clear bottom-right
180  IFC%=0ANDB%=0J%=0:CLS:VDU19,3,RND(7);0;0;0;:TIME=0:REPEATUNTILTIME>100
REM When erasing, start at random point in shuffled sequence
190  IFC%=1O%=RND(1279)-1
REM Repeat indefinitely
200 UNTIL0

Run the program in JSBeeb:

The shuffle algorithm is a bit slow. Is there a quicker shuffle (or passable "fake" shuffle) I can use?

:?:
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

From the January 1984 issue of Computer Answers magazine, a program that generates the sound of what the article calls a "car engine", but it has echoes of Daredevil Dennis:

Article
Article

Code: Select all

 10 FORI%=1TO40
 20 SOUND&100,-15,3,2
 30 SOUND&101,-8,80,1
 40 NEXT
 50 SOUND0,-15,3,50
 60 FORI%=10TO150STEP10
 70 SOUND1,0,I%,1
 80 NEXT
 90 X%=50
100 REPEAT
110 A$=INKEY$(0)
120 IF A$="Z" THEN X%=X%-2
130 IF A$="X" THEN X%=X%+2
140 IF A$="G" THEN X%=X%-30
150 SOUND1,0,X%,1
160 SOUND0,-15,3,1
170 UNTILA$="S"

Run in JSBeeb:
:idea:
Last edited by lurkio on Thu May 16, 2019 1:42 am, edited 2 times in total.
User avatar
BigEd
Posts: 3735
Joined: Sun Jan 24, 2010 10:24 am
Location: West Country
Contact:

Re: Any short type-ins for unattended Beebs?

Post by BigEd »

I was at TNMoC (The National Museum of Computing, on the Bletchley Park campus) yesterday and managed to type in dv8's version of Valentin Alibillo's Pi Spigot program:
IMG_2110-pi-spigot-basic-tnmoc-albillo-2.JPG
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

Compacted version of a nice "Matrix rain" effect by @electron_greg:

Code: Select all

e=7:D=6:MO.2:F.X=0TO19:S=RND(3):C=RND(15):F.Y=0TO31-RND(2)S.S:C.C:V.31X,Y,RND(26)+64:C=C+1+15*(C=15):N.,:C=3:V.5:REP.V.19,D,4,0;0;19,e,6,0;0;:TI.=0:REP.U.TI.>6:V.19,C,0;0;:e=e+1+15*(e=15):D=D+1+15*(D=15):C=C+1+15*(C=15):U.0
http://bbcmicro.co.uk/jsbeeb/play.php?p ... 3AFD300DFF

:idea:
User avatar
BigEd
Posts: 3735
Joined: Sun Jan 24, 2010 10:24 am
Location: West Country
Contact:

Re: Any short type-ins for unattended Beebs?

Post by BigEd »

Love it!
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

This one, from Katie Anderson, is kind of brilliant:

Code: Select all

10 MODE 1
20 N=1
30 DIM A(8)
40 FOR I=1 TO 8
50 FOR J=1 TO 8
60 A(J)=N
70 NEXT J
80 A(I)=255
90 N=N*2
100 VDU 23,96+I,A(1),A(2),A(3),A(4),A(5),A(6),A(7),A(8)
110 NEXT I
120 PRINT "abcdefghgfedcb";
130 GOTO 120

The whole @bbcmicrobot account is worth a look too.

:idea:
User avatar
BigEd
Posts: 3735
Joined: Sun Jan 24, 2010 10:24 am
Location: West Country
Contact:

Re: Any short type-ins for unattended Beebs?

Post by BigEd »

Some spectacular contributions there! And a twitter account which posts animated renderings from an emulator in response to code snippets is a great idea.

I think we need to preserve some of the best, in case this account (once again) gets deleted.
elkrepair
Posts: 44
Joined: Tue Nov 13, 2018 1:53 pm
Contact:

Re: Any short type-ins for unattended Beebs?

Post by elkrepair »

A ball of string from a 1984 Ian Graham book:

10 MODE1
20 VDU29,640;512;
30 GCOL0,2
40 MOVE0,0
50 FOR A=0 TO 315 STEP 0.1
60 DRAW 500*COS(A)*SIN(A*0.98),500*SIN(A)
70 NEXT
Elk rev 4 & Plus1
BBC B rev 7 & Cumana Disc Drive
BBC micro:bit
RaspberryPi B+ & 3B & Zero
Abit BP6
User avatar
Andrew_Waite
Posts: 243
Joined: Tue Aug 30, 2016 3:58 pm
Contact:

Re: Any short type-ins for unattended Beebs?

Post by Andrew_Waite »

Draw a Sierpinski Triangle using a Chaos Game method.

Code: Select all

10 MODE0:x=0:y=0
20 FOR I%=1 TO 1000000:V%=RND(3)
30 IF V%=1 x=x/2:y=y/2
40 IF V%=2 x=100+(100-x)/2:y=173-(173-y)/2
50 IF V%=3 x=200-(200-x)/2:y=y/2
60 PLOT 69,x*5.8,y*5.8:NEXT
Last edited by Andrew_Waite on Sun Nov 01, 2020 6:01 pm, edited 3 times in total.
User avatar
Andrew_Waite
Posts: 243
Joined: Tue Aug 30, 2016 3:58 pm
Contact:

Re: Any short type-ins for unattended Beebs?

Post by Andrew_Waite »

Drawing more fractals, this time Julia Sets.

Firstly in MODE 0, with creal=-0.8 and cimag=0.156

Code: Select all

   10 MODE 0:VDU29,640;512;
   20 creal=-0.8
   30 cimag=0.156
   40 FOR v=-512 TO 512 STEP 4
   50 FOR h=-640 TO 640 STEP 2
   60 x=h/400:y=v/550
   70 FOR i=1 TO 50:zreal=(x*x)-(y*y)+creal:zimag=(x*y*2)+cimag
   80 IF (zreal*zreal)>1000 THEN GCOL0,1:i=50:GOTO100
   90 x=zreal:y=zimag
  100 NEXT
  110 PLOT69,h,v:GCOL0,0
  120 NEXT:NEXT
A colourised version of the Julia Set above, in MODE 1

Code: Select all

   10 MODE 1:VDU29,640;512;
   20 creal=-0.8
   30 cimag=0.156
   40 FOR v=-512 TO 512 STEP 4
   50 FOR h=-640 TO 640 STEP 2
   60 x=h/400:y=v/550
   70 FOR i=1 TO 50:zreal=(x*x)-(y*y)+creal:zimag=(x*y*2)+cimag
   80 IF (zreal*zreal)>1000 THEN GCOL0,i:i=50:GOTO100
   90 x=zreal:y=zimag
  100 NEXT
  110 PLOT69,h,v:GCOL0,0
  120 NEXT:NEXT
A different Julia Set, with creal=-0.25 and cimag=0.65

Code: Select all

   10 MODE 1:VDU29,640;512;
   20 creal=-0.25
   30 cimag=0.65
   40 FOR v=-512 TO 512 STEP 4
   50 FOR h=-640 TO 640 STEP 4
   60 x=h/400:y=v/400
   70 FOR i=1 TO 50:zreal=(x*x)-(y*y)+creal:zimag=(x*y*2)+cimag
   80 IF (zreal*zreal)>1000 THEN GCOL0,i:i=50:GOTO100
   90 x=zreal:y=zimag
  100 NEXT
  110 PLOT69,h,v:GCOL0,0
  120 NEXT:NEXT
The same Julia Set, but zoomed in on a central section.

Code: Select all

   10 MODE 1:VDU29,640;512;
   20 creal=-0.25
   30 cimag=0.65
   40 FOR v=-512 TO 512 STEP 4
   50 FOR h=-640 TO 640 STEP 4
   60 x=h/2000:y=v/2000
   70 FOR i=1 TO 50:zreal=(x*x)-(y*y)+creal:zimag=(x*y*2)+cimag
   80 IF (zreal*zreal)>1000 THEN GCOL0,i:i=50:GOTO100
   90 x=zreal:y=zimag
  100 NEXT
  110 PLOT69,h,v:GCOL0,0
  120 NEXT:NEXT
User avatar
Andrew_Waite
Posts: 243
Joined: Tue Aug 30, 2016 3:58 pm
Contact:

Re: Any short type-ins for unattended Beebs?

Post by Andrew_Waite »

Another nice fractal drawn using a Chaos Game method. https://bbc.godbolt.org/?embedBasic=10% ... %20NEXT%0A

Code: Select all

   10 MODE0:a=1/2:x=10:y=10:W%=6
   20 FOR I%=1 TO 1000000
   30 REPEAT:V%=RND(4):UNTIL V%<>W%
   40 :
   50 IF V%=1 x=x*a       :y=y*a
   60 IF V%=2 x=100+(x*a) :y=y*a
   70 IF V%=3 x=x*a       :y=100+(y*a)
   80 IF V%=4 x=100+(x*a) :y=100+(y*a)
  100 :
  110 PLOT 69,x*5,y*5:W%=V%
  120 NEXT
Last edited by Andrew_Waite on Tue Nov 03, 2020 4:50 am, edited 2 times in total.
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

Andrew_Waite wrote:
Sun Nov 01, 2020 6:01 pm
Another nice fractal drawn using a Chaos Game method.
These are all great code samples. I wonder if you'd like to make them more accessible by generating quick JSBeeb links for them using this handy web form that BigEd posted recently?:

https://www.masswerk.at/pet/beeb-link/

:?:
stephen_usher
Posts: 142
Joined: Sun Apr 10, 2016 2:47 pm
Location: Oxford, UK.
Contact:

Re: Any short type-ins for unattended Beebs?

Post by stephen_usher »

I did a few simple programs for people to type in for an exhibit at the Oxford Museum of the History of Science back in 2014, with a Beeb and a Sinclair QL. I'll attach the PDFs below.
Attachments
radial-cosine-example.pdf
(17.9 KiB) Downloaded 15 times
text-bounce-example.pdf
(23.85 KiB) Downloaded 16 times
simple-synth-basic-examples.pdf
(17.43 KiB) Downloaded 13 times
User avatar
JasonStonier
Posts: 437
Joined: Mon Dec 10, 2018 8:10 pm
Location: Dorset
Contact:

Re: Any short type-ins for unattended Beebs?

Post by JasonStonier »

lurkio wrote:
Tue Feb 11, 2020 7:50 pm
This one, from Katie Anderson, is kind of brilliant:
That is incredibly elegant.
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

Adapted from 8-bit Show And Tell's 10 PRINT RACER for the Commodore PET:

Code: Select all

1MODE1:VDU23,128,1,2,4,8,16,32,64,128,23,129,128,64,32,16,8,4,2,1:A%=&87:H%=0:R$=STRING$(75," "):PRINT'''"  Press a key ";::*FX4,1
2*FX11,1
3*FX15
4IFGETVDU12,23,1,0;0;0;0;:IFRND(-TIME)
5REPEAT:R$="":FORI%=1TO75:M$=CHR$(127+RND(2)):R$=R$+M$:NEXT:*FX15
10C%=20:R%=13:W%=15:D%=0:U%=2
20L%=0:REPEAT:X%=RND(2)
30IFX%=1R%=R%-1:IFR%<1R%=1
40IFX%=2R%=R%+1:IFR%+W%>37R%=37-W%
50N%=RND(35):COLOURU%+1:PRINTMID$(R$,N%,R%)SPCW%MID$(R$,N%,40-R%-W%);
60D%=D%+1:L%=L%+1:IFL%>49 L%=0:U%=(U%+1)MOD3:IFW%>6W%=W%-1
70IFD%<31UNTILFALSE
75K%=INKEY(1):IFK%=90ORK%=136C%=C%-1
80IFK%=88ORK%=137C%=C%+1
90VDU31,C%,1:IF(USR(&FFF4)AND&FF00)DIV256=32COLOUR3:VDU11,42,31,0,31:UNTILFALSE
200UNTILTRUE:COLOUR3:VDU11,42,31,17,3:PRINT"CRASH!":IFD%>H%H%=D%
205VDU31,10,7:PRINT"SCORE:";D%"   HIGH:";H%
210TIME=0:REPEATUNTILTIME>100:*FX15
220IFGETCLS:UNTILFALSE
>>> Play in web-browser <<<

:idea:
User avatar
JasonStonier
Posts: 437
Joined: Mon Dec 10, 2018 8:10 pm
Location: Dorset
Contact:

Re: Any short type-ins for unattended Beebs?

Post by JasonStonier »

I imagine this may have been posted before, but I just discovered this:

https://www.bbcmicrobot.com/

Some really elegant code being displayed on there.

This one particularly impresses me for some reason:

Code: Select all

0REPEAT:UNTILTIME>3050:REPEATFORW%=40TO1STEP-1:VDU23;1,W%;0;0;0*INKEY3:NEXT:FORW%=2TO40:VDU23;1,W%;0;0;0*INKEY3:NEXT:REPEATUNTIL0
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

From @coprolite9000 on Twitter:

>>> Play in browser <<<

Code: Select all

10MO.2
15F.a=0TO90S.1
20PROCd(640,512,900-a*10,a MOD15+1,a/4)
30N.
40P=0:REP.F.I=0TO8:V.19,(P+I)MOD15+1,VALM."0467731",I+1,1);0;:N.I:P=P+1:U.0
50END
60DEFPROCd(x,y,r,p,a)
70GC.0,p
80LOC.c,s:c=r*COSa:s=r*SINa
90MOVEx+c,y+s:MOVEx+s,y-c:PL.85,x-s,y+c
100MOVEx-c,y-s:PL.85,x+s,y-c
110E.
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

From @RLabibov on Twitter:

>>> Play in browser (accelerated) <<<

Code: Select all

1 MODE 0:VDU 29,640;512;5,0
2 t=1.732051:x=0:y=0
3 REPEAT
4 r%=RND(200)
5 IF r%<4 THEN x=RND(1)*2-1:y=RND(1)*2:GO.10
6 e=(-(r%<52)+(r%>=52))
7 z=x
8 x=(x+e+t*e*y)/2
9 y=(4+t-t*e*z+y)/2
10 PLOT69,16*x,16*y
11 UNTIL0
Screenshot 2021-01-03 at 20.20.39.png
User avatar
Richard Russell
Posts: 1883
Joined: Sun Feb 27, 2011 10:35 am
Location: Downham Market, Norfolk
Contact:

Re: Any short type-ins for unattended Beebs?

Post by Richard Russell »

lurkio wrote:
Sun Jan 03, 2021 8:59 pm
Play in browser (accelerated)
Or if you're impatient, play in BBCSDL (needs a desktop browser - not Safari - or Chrome for Android).
I am suffering from 'cognitive decline' and depression. If you have a comment about the style or tone of this message please report it to the moderators by clicking the exclamation mark icon, rather than complaining on the public forum.
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

Richard Russell wrote:
Sun Jan 03, 2021 10:12 pm
if you're impatient, play in BBCSDL
Very nice! But it's awfully fast! Doesn't give you enough time to appreciate the strangely compelling creepiness of the slowly evolving image the way the Beeb version does!

:)
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

From @Kweepa on Twitter:

http://bbcmicro.co.uk/jsbeeb/play.php?m ... %3AEND.%0A

Code: Select all

F.Z=30TO10S.-1
IFZ=25MOVE160,-400:PROCa
V=2E3/Z:W=2E3/(Z+1)
F.X=-8TO7
Q=V:R=W:GC.0,1:IF1A.RND Q=W:R=V:GC.16,0
A=X*Q:B=X*R:C=-6*Q:D=-6*R
MOVEA,C:MOVEA,C-Q:PL.85,B+R,D:PL.85,B+R,D-R
GC.0,7:MOVEA,C:DR.B+R,D
N.,:*FX21,0
IFGET V.4:CLS:V.5:MOVE160,-400:PROCa:*FX21,0
IFGET V.4:CLS:V.5:TIME=0:REP.U.TIME>500:V.4:CLS:*FX21,0
END
DEFPROCa:V.23,128,32,32,12,24,16,0,0,0,18,0,1,128,23,128,0,24,16,0,0,0,20,20,8,18,0,7,128,23,128,6,2,20,42,42,20,0,0,25,0,192,255,244,255,18,0,0,128,23,128,12,8,0,0,8,28,28,4,25,0,192,255,252,255,18,0,3,128
V.23,128,20,0,62,0,62,0,62,0,25,0,192,255,228,255,18,0,1,128,23,128,0,20,0,62,0,62,0,62,8,18,0,7,128:END.
Chuckie
Posts: 41
Joined: Thu Jun 20, 2019 1:21 pm
Contact:

Re: Any short type-ins for unattended Beebs?

Post by Chuckie »

10 PRINT "HELLO WORLD!"
20 GOTO 10
User avatar
lurkio
Posts: 3142
Joined: Wed Apr 10, 2013 12:30 am
Location: Doomawangara
Contact:

Re: Any short type-ins for unattended Beebs?

Post by lurkio »

From @Kweepa again:

http://bbcmicro.co.uk/jsbeeb/play.php?e ... AGOTO90%0A

Code: Select all

MODE2
FORX=0TO2:FORY=-1TO8:VDU29,16+248*(1ANDY)+496*X;60+128*Y;
FORZ%=0TO15:IF1ANDY GCOL0,Z% ELSEGCOL0,15-Z%
FORQ%=8*Z% TO8*Z%+4STEP4
P%=Q%+Q%
MOVEP%,0:DRAW0,Q%:DRAW-P%,0:DRAW0,-Q%:DRAWP%,0
NEXT,,,
$@%="04267624"
A=A+1:FORI=0TO15:VDU19,(A+I)AND15,@%?(I/2);0;5:NEXT:GOTO90
Post Reply

Return to “8-bit acorn software: other”