Missing Adventure games

want to request software or documentation that you can't find online? post in here!
User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Wed Jun 21, 2017 9:32 pm

fuzzel wrote:As Topologika are still going as an educational software provider, has anyone contacted them to see if they have any old stock as there are other missing games of theirs as well?

I've been in touch with Brian Kerslake, Jonathan Partington and Jon Thackray, all of Topologika as was.

They said they don't have any old stock, but Jon Thackray did mention that he had a means of rebuilding some or all released Beeb game versions from source. Sadly, my email conversation with him petered out without producing any Beeb-specific results, although it did prompt him to submit some C source-code to the IF Archive.

See here for more:

:idea:
Last edited by lurkio on Wed Jun 21, 2017 9:33 pm, edited 1 time in total.

User avatar
Dave_E
Posts: 696
Joined: Fri Jun 16, 2006 12:55 pm
Location: Middlesbrough
Contact:

Re: Missing Adventure games

Postby Dave_E » Wed Jun 21, 2017 9:33 pm

Ah, looks like it wasn't it there. I've updated the download now.

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Wed Jun 21, 2017 9:34 pm

Dave_E wrote:Ah, looks like it wasn't it there. I've updated the download now.

Any progress on Castaway, Dave?

:?:

User avatar
Dave_E
Posts: 696
Joined: Fri Jun 16, 2006 12:55 pm
Location: Middlesbrough
Contact:

Re: Missing Adventure games

Postby Dave_E » Wed Jun 21, 2017 9:35 pm

tomorrow...

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Thu Jun 22, 2017 10:37 am

Dave_E wrote:The Elk version is available though, so it's not *too* traumatizing. The BBC version is likely exactly the same except runs in Mode 7! http://www.everygamegoing.com/landing/i ... _Doom.html

Sure, and you can probably hack the machine-code file to switch to MODE 7 instead of MODE 6 because that's what I actually once did to the Elk version of Spy Snatcher. The only problem was that the game required an &E00 DFS, which is non-standard on a Model B (but not on a Master, on which my MODE7 hack of Spy Snatcher seemed to run fine (in BeebEm)).

So, ideally we'd still like to have standard &1900-DFS MODE7 versions of Spy Snatcher and Hezarin for the Beeb, but, as you say, their absence isn't *too* traumatizing, given that we do have Elk versions.

:idea:

fuzzel
Posts: 195
Joined: Sun Jan 02, 2005 1:16 pm
Location: Cullercoats, North Tyneside

Re: Missing Adventure games

Postby fuzzel » Fri Jun 23, 2017 3:04 pm

It would be great to have Hezarin converted to run in mode7, it looks rubbish in mode 6.

User avatar
Arcadian
Posts: 2733
Joined: Fri Nov 24, 2000 12:16 pm
Contact:

Re: Missing Adventure games

Postby Arcadian » Fri Jun 23, 2017 5:03 pm

Can't help with a Mode 7 conversion, but if you fancy playing Hezarin (plus Last Days of Doom) in Mode 0 (or is it 3?) then here's the Archimedes version ...
Attachments
Last Days of Doom, The + Hezarin (1993)(Topologika).zip
(338.81 KiB) Downloaded 19 times
For a "Complete BBC Games Archive" visit www.bbcmicro.co.uk

Image
ABug Leicestershire (17-19 November 2017)

User avatar
Arcadian
Posts: 2733
Joined: Fri Nov 24, 2000 12:16 pm
Contact:

Re: Missing Adventure games

Postby Arcadian » Fri Jun 23, 2017 5:09 pm

Also, I'm not sure if this has made it to the interweb before now, but here's the Arc release of Countdown to Doom, Return to Doom and Philosopher's Quest...
Attachments
Countdown to Doom + Return to Doom + Philosopher's Quest (1991)(Topologika).zip
(272.78 KiB) Downloaded 21 times
For a "Complete BBC Games Archive" visit www.bbcmicro.co.uk

Image
ABug Leicestershire (17-19 November 2017)

fuzzel
Posts: 195
Joined: Sun Jan 02, 2005 1:16 pm
Location: Cullercoats, North Tyneside

Re: Missing Adventure games

Postby fuzzel » Sat Jun 24, 2017 10:34 am

Has anyone played Spy Snatcher ? I've just had a quick go (damn those mode 6 graphics) and it looks "challenging" to say the least.

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Sat Jun 24, 2017 11:01 am

fuzzel wrote:Has anyone played Spy Snatcher ? I've just had a quick go (damn those mode 6 graphics)

There are "graphics"?

:?:

UPDATE: Here's a hacked version of Spy Snatcher that seems to run okay in MODE 7 in Master 128 mode in BeebEm:

:idea:

fuzzel
Posts: 195
Joined: Sun Jan 02, 2005 1:16 pm
Location: Cullercoats, North Tyneside

Re: Missing Adventure games

Postby fuzzel » Sat Jun 24, 2017 2:37 pm

Thanks for the Spy Snatcher file Lurkio. Regarding "graphics" don't be so pedantic ! I meant the visual quality of the mode 6 text (in my eyes graphics for short). :)

User avatar
leenew
Posts: 3332
Joined: Wed Jul 04, 2012 3:27 pm
Location: Doncaster, Yorkshire

Re: Missing Adventure games

Postby leenew » Mon Jul 03, 2017 4:11 pm

Dave_E wrote:tomorrow...

Tomorrow, Tomorrow, I loves ya Tomorrow, your always a day....a.... waaaaaaaaaay :D 8-[ :- :lol:

Lee.

fuzzel
Posts: 195
Joined: Sun Jan 02, 2005 1:16 pm
Location: Cullercoats, North Tyneside

Re: Missing Adventure games

Postby fuzzel » Mon Jul 03, 2017 7:58 pm

Consider yourself nudged Dave_E !

User avatar
leenew
Posts: 3332
Joined: Wed Jul 04, 2012 3:27 pm
Location: Doncaster, Yorkshire

Re: Missing Adventure games

Postby leenew » Wed Jul 05, 2017 7:39 am

I have found a new adventure game in "Computer Projects" by Piccolo books.
The only trouble is it needs typing in :D
Does anyone have access to a scanner and could do some OCR on it?
I have photographed the listing here: https://1drv.ms/u/s!An_TvEOp-wxGhHSSr4U-cFqEet8a

Thanks,

Lee

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Wed Jul 05, 2017 12:47 pm

leenew wrote:I have found a new adventure game in "Computer Projects" by Piccolo books. The only trouble is it needs typing in :D
Does anyone have access to a scanner and could do some OCR on it? I have photographed the listing here: https://1drv.ms/u/s!An_TvEOp-wxGhHSSr4U-cFqEet8a

Here are two different attempts at OCRing your photos (in Adobe Acrobat):


I think a scanner would definitely help!

:idea:

User avatar
leenew
Posts: 3332
Joined: Wed Jul 04, 2012 3:27 pm
Location: Doncaster, Yorkshire

Re: Missing Adventure games

Postby leenew » Wed Jul 05, 2017 2:10 pm

Hmmm.. looks near enough to me :-k
Does it work? :wink:

Lee

User avatar
davidb
Posts: 1831
Joined: Sun Nov 11, 2007 10:11 pm
Contact:

Re: Missing Adventure games

Postby davidb » Wed Jul 05, 2017 2:13 pm

I ran the pages through Tesseract and cleaned up the output. It's not really designed for this kind of text. Feel free to fix any errors I've introduced. ;)

Code: Select all

10 REM "ADVENT"
50 DIM V$(20),O$(25),D$(25),L(25),M(25),L$(30,2),N$(30)
60 GOSUB 1340:LET LC=1:LET NC=0:LET BF=0:LET DF=0:LET LF=0:LET GF=0:GOSUB 1190
70 GOSUB 930
80 IF V>6 THEN GOTO 130
90 IF DF=1 AND RND(1)<.6 THEN LET OB=8:GOSUB 1070:GOTO 150
100 LET NL=VAL(MID$(N$(LC),2*V-1,2))
110 IF NL>0 THEN LET LC=NL:PRINT "O.K.":GOSUB 1190:GOTO 150
120 PRINT "YOU CAN'T GO THAT WAY !":GOTO 150
130 ON V-6 GOSUB 360,540,1190,210,300,420,590,710,790,830,830,860,860
140 IF V=10 AND O=4 THEN GOTO 70
150 IF DF=1 AND RND(1)<.2 THEN GOSUB 1130:GOTO 70
160 IF LC>4 AND RND(1)<.2 AND DF=0 THEN GOSUB 1090
170 IF LC>4 AND DF=1 THEN LET L(8)=-LC
180 IF LC<5 THEN LET DF=0:LET L(8)=0
190 GOTO 70
200 REM ***** TAKE *****
210 IF L(O)=99 THEN PRINT "YOU'VE ALREADY GOT IT !":RETURN
220 IF ABS(L(O))<>LC THEN PRINT "IT ISN'T HERE !":RETURN
230 IF L(O)<0 THEN PRINT "YOU MUST BE JOKING !":RETURN
240 IF NC=5 THEN PRINT "YOU CAN'T CARRY ANY MORE":RETURN
250 IF O<11 OR O>15 THEN GOTO 280
260 IF L(6)=-LC THEN LET OB=6:GOSUB 1070:RETURN
270 IF L(7)=-LC THEN LET OB=7:GOSUB 1070:RETURN
280 PRINT "O.K.":LET NC=NC+1:LET L(O)=99:RETURN
290 REM ***** DROP *****
300 IF L(O)<>99 THEN PRINT "YOU HAVEN'T GOT IT !":RETURN
310 LET NC=NC-1
320 IF O<>14 OR L(15)=LC THEN PRINT "O.K.":LET L(O)=LC:RETURN
330 PRINT "IT CRASHES TO THE FLOOR !!":LET L(14)=0:LET L(16)=LC:LET MS=MS-30
340 RETURN
350 REM ***** LIST *****
360 LET CF=0:FOR K=1 TO NO:IF L(K)<>99 THEN GOTO 390
370 IF CF=0 THEN PRINT "YOU ARE CARRYING...":LET CF=1
380 PRINT D$(K)
390 NEXT K:IF CF=0 THEN PRINT "YOU AREN'T CARRYING ANYTHING !"
400 RETURN
410 REM ***** WAVE *****
420 IF L(O)<>99 THEN PRINT "YOU HAVEN'T GOT IT !":RETURN
430 IF O<>3 THEN PRINT "IF IT MAKES YOU HAPPY !":RETURN
440 IF LC<>7 AND LC<>14 THEN PRINT "NOTHING HAPPENS": RETURN
450 IF BF=1 THEN GOTO 480
460 PRINT "A CRYSTAL BRIDGE APPEARS !!"
470 LET L(10)=-7:LET M(10)=-14:LET A$="14":LET B$="07":GOTO 500
480 PRINT "THE BRIDGE VANISHES !!"
490 LET L(10)=0:LET M(10)=0:LET A$="00":LET B$="00"
500 LET N$(7)=LEFT$(N$(7),6)+A$+MID$(N$(7),9)
510 LET N$(14)=LEFT$(N$(14),2)+B$+MID$(N$(14),5)
520 LET BF=1-BF:RETURN
530 REM ***** SCORE *****
540 LET SC=0:FOR K=11 TO 15:IF L(K)=1 THEN LET SC=SC+30
550 IF L(K)=99 THEN LET SC=SC+10
560 NEXT K:PRINT "YOUR SCORE IS "; SC;" OUT OF ";MS:IF SC<MS THEN RETURN
570 PRINT:PRINT "YOU HAVE COMPLETED YOUR QUEST !!":PRINT:STOP
580 REM ***** THROW *****
590 IF L(O)<>99 THEN GOTO 290
600 IF O<>5 THEN GOTO 670
610 LET B=0:IF L(6)=-LC THEN LET B=6
620 IF L(7)=-LC THEN LET B=7
630 IF B=0 THEN GOTO 290
640 LET NC=NC-1:PRINT "THE BIRD ATTACKS THE ";O$(B)
650 IF B=7 THEN PRINT "AND DRIVES IT AWAY !!":LET L(7)=0:LET L(5)=LC:RETURN
660 IF B=6 THEN PRINT "AND GETS BURNED TO A CINDER !!":LET L(5)=0:RETURN
670 IF O<>4 OR DF=0 THEN GOTO 290
680 IF RND(1)<.1 THEN PRINT "THE DWARF DODGES IT !":GOTO 290
690 PRINT "THE DWARF VANISHES IN SMOKE":LET L(8)=0:LET DF=0:GOTO 290
700 REM ***** FIGHT *****
710 IF O<>6 THEN PRINT "DON'T BE SILLY !!":RETURN
720 PRINT "WHAT - WITH YOUR BARE HANDS ??!!"
730 LET G$=INKEY$(0):IF G$="" THEN GOTO 730
740 LET G=ASC(G$):IF G>96 THEN LET G=G-32
750 LET G$=CHR$(G):IF G$<>"Y" AND G$<>"N" THEN GOTO 730
760 IF G$="N" THEN RETURN
770 PRINT "YOU DEFEAT IT !!":PRINT "IT'S A STRANGE WORLD !":LET L(6)=0:RETURN
780 REM ***** SAY *****
790 IF (LC<>16 AND LC<>1) OR O<>17 THEN PRINT "O.K. '";B$;"'":RETURN
800 PRINT "YOU FEEL YOURSELF SPINNING ROUND ...":FOR Z=1 T0 400:NEXT Z
810 LET LC=17-LC:GOSUB 1190:RETURN
820 REM ***** LIGHT/EXTINGUISH *****
830 IF O<>1 THEN PRINT "DON'T BE SILLY !":RETURN
840 LET LF=V-16:RETURN
850 REM ***** LOCK/UNLOCK *****
860 IF O<>9 THEN PRINT "DON'T BE SILLY !":RETURN
870 IF L(2)<>99 THEN PRINT "YOU HAVEN'T ANY KEYS !":RETURN
880 LET GF=19-V:IF GF=0 THEN LET A$="00":LET B$="00":GOTO 900
890 LET A$="04":LET B$="03"
900 LET N$(3)=LEFT$(N$(3),8)+A$+MID$(N$(3),11):LET N$(4)=LEFT$(N$(4),10)+B$
910 RETURN
920 REM ***** DECODE COMMAND *****
930 LET A$="":LET B$="":PRINT "WHAT NOW ";:INPUT K$:LET LK=LEN(K$):LET K=0
940 LET K=K+1:IF K>LK THEN GOTO 960
950 IF MID$(K$,K,1)<>" " THEN GOTO 940
960 LET A$=LEFT$(K$,K-1):LET LA=LEN(A$)
970 LET V=0:FOR C=1 TO NV:IF A$=LEFT$(V$(C),LA) THEN LET V=C:LET C=99
980 NEXT C:IF V=0 THEN GOTO 1040
990 IF V<10 THEN RETURN
1000 IF K>=LK THEN PRINT A$;" WHAT ...";:INPUT B$:LET LB=LEN(B$):GOTO 1020
1010 LET B$=MID$(K$,K+1):LET LB=LEN(B$)
1020 LET O=0:FOR C=1 TO NO:IF B$=LEFT$(O$(C),LB) THEN LET O=C:LET C=99
1030 NEXT C:IF O>0 THEN RETURN
1040 PRINT:PRINT "SORRY - I DON'T UNDERSTAND"
1050 PRINT:GOTO 930
1060 REM ***** CAN'T DO *****
1070 PRINT "THE ";O$(OB);" STOPS YOU !!":RETURN
1080 REM ***** DWARF *****
1090 IF L(4)<>0 THEN PRINT "A DWARF COMES ROUND A CORNER !":LET DF=1:RETURN
1100 PRINT "SUDDENLY, A DWARF APPEARS. HE"
1110 PRINT "HURLS AN AXE AT YOU, CURSES"
1120 PRINT "WHEN IT MISSES, AND RUNS AWAY":LET L(4)=LC:RETURN
1130 PRINT "THE DWARF THROWS A KNIFE AT YOU ..."
1140 FOR Z=1 TO 400:NEXT Z
1150 IF RND(1)<.8 THEN PRINT "IT MISSES YOU !":RETURN
1160 PRINT "IT HITS YOU... YOU SINK":PRINT "TO THE FLOOR, MORTALLY WOUNDED !"
1170 GOSUB 530:PRINT:STOP
1180 REM ***** LOOK AROUND *****
1190 CLS:PRINT
1200 IF LF=1 AND (L(1)=LC OR L(1)=99) THEN GOTO 1220
1210 IF LC>4 THEN PRINT "IT IS TOO DARK TO SEE...":RETURN
1220 PRINT L$(LC,1):PRINT L$(LC,2)
1230 LET OF=0:FOR K=1 TO NO:IF ABS(L(K))<>LC AND ABS(M(K))<>LC THEN GOTO 1260
1240 IF OF=0 THEN PRINT "YOU SEE ...":LET OF=1
1250 PRINT D$(K)
1260 NEXT K
1270 IF LC<>3 AND LC<>4 THEN GOTO 1300
1280 PRINT "THE GRATING IS ";:IF GF=1 THEN PRINT "UN";
1290 PRINT "LOCKED"
1300 IF LC=16 THEN PRINT "A HOLLOW VOICE SAYS 'HELLO'"
1310 IF DF=1 AND LC>4 THEN PRINT "THERE IS A NASTY DWARF NEXT TO YOU..."
1320 RETURN
1330 REM ***** READ DATA *****
1340 READ NV:FOR K=1 TO NV:READ V$(K):NEXT K
1350 READ NO:FOR K=1 TO NO:READ O$(K),D$(K),L(K),M(K):NEXT K
1360 READ NL:FOR K=1 TO NL:READ L$(K,1),L$(K,2),N$(K):NEXT K
1370 LET MS=150:RETURN
1380 DATA 19,"NORTH","EAST","SOUTH","WEST","DOWN","UP","LIST","SCORE","LOOK"
1390 DATA "TAKE","DROP","WAVE","THROW","FIGHT","SAY","EXTINGUISH","LIGHT"
1400 DATA "UNLOCK","LOCK"
1410 DATA 17
1420 DATA "LANTERN","A BRASS LANTERN",1,0
1430 DATA "KEYS","A BUNCH OF KEYS",1,0
1440 DATA "WAND","A MAGIC WAND",4,0
1450 DATA "AXE","A SMALL GOLDEN AXE",0,0
1460 DATA "BIRD","A LITTLE SINGING BIRD",5,0
1470 DATA "DRAGON","A LARGE GREEN DRAGON !",-15,0
1480 DATA "SNAKE","A COILED HISSING SNAKE",-6,0
1490 DATA "DWARF","A NASTY DWARF WITH A SHARP KNIFE !",0,0
1500 DATA "GRATING","A GRATING SET IN CONCRETE",-3,-4
1510 DATA "BRIDGE","A CRYSTAL BRIDGE OVER THE CHASM",0,0
1520 DATA "SILVER","SOME BARS OF SILVER",6,0
1530 DATA "GOLD","A PILE OF GOLD PIECES",14,0
1540 DATA "JEWELS","A BAG OF JEWELS",13,0
1550 DATA "VASE","A DELICATE MING VASE",15,0
1560 DATA "CUSHION","AN ORNATE CUSHION",16,0
1570 DATA "","SOME WDRTHLESS BITS OF POTTERY",0,0
1580 DATA "HELLO","",0,0
1590 DATA 16
1600 DATA "YOU ARE INSIDE A STONE HUT"
1610 DATA "THERE IS A DOOR TO THE WEST"
1620 DATA "000000020000"
1630 DATA "A PATH LEADS SOUTH."
1640 DATA "THERE IS A HUT TO THE EAST"
1650 DATA "000103000000"
1660 DATA "YOU ARE IN A SHALLOW DEPRESSION"
1670 DATA "A PASSAGE LEADS UNDERGROUND"
1680 DATA "020000000000"
1690 DATA "YOU'RE IN AN UNDERGROUND PASSAGE"
1700 DATA "LIGHT FILTERS THROUGH A GRATING"
1710 DATA "000000050000"
1720 DATA "YOU ARE IN AN EAST-WEST PASSAGE"
1730 DATA "WITH A HOLE IN THE SOUTH WALL"
1740 DATA "000408060000"
1750 DATA "YOU ARE IN A GREAT HALLWAY, WITH"
1760 DATA "DOORS TO THE EAST AND WEST"
1770 DATA "000500070000"
1780 DATA "YOU ARE ON THE EAST BANK OF A"
1790 DATA "DEEP CHASM"
1800 DATA "000600000000"
1810 DATA "YOU ARE IN A MAZE OF TWISTY"
1820 DATA "PASSAGES, ALL ALIKE"
1830 DATA "050910110000"
1840 DATA "YOU ARE IN A MAZE OF TWISTY"
1850 DATA "PASSAGES, ALL ALIKE"
1860 DATA "110910080000"
1870 DATA "YOU ARE IN A MAZE OF TWISTY"
1880 DATA "PASSAGES, ALL ALIKE"
1890 DATA "080910120000"
1900 DATA "YOU ARE IN A MAZE OF TWISTY"
1910 DATA "PASSAGES, ALL ALIKE"
1920 DATA "090812110000"
1930 DATA "YOU ARE IN A MAZE OF TWISTY"
1940 DATA "PASSAGES, ALL ALIKE"
1950 DATA "111013120000"
1960 DATA "YOU HAVE REACHED A DEAD END"
1970 DATA ""
1980 DATA "120000000000"
1990 DATA "YOU ARE ON THE WEST BANK OF THE"
2000 DATA "CHASM. A PASSAGE LEADS NORTH"
2010 DATA "151300000000"
2020 DATA "YOU ARE IN A LARGE CAVERN WITH A"
2030 DATA "STAIRCASE SPIRALLING UPWARDS"
2040 DATA "000014000016"
2050 DATA "THE WAY IS BLOCKED BY A ROCKFALL"
2060 DATA "A STAIRCASE SPIRALS DOWNWARDS"
2070 DATA "000000001500"
Attachments
advent.zip
(7.43 KiB) Downloaded 23 times

User avatar
leenew
Posts: 3332
Joined: Wed Jul 04, 2012 3:27 pm
Location: Doncaster, Yorkshire

Re: Missing Adventure games

Postby leenew » Mon Jul 10, 2017 10:34 am

Hi,
I have checked the listing and found just 1 error (An O was OCR'd as a 0). Pretty good going =D>
I have had to make one alteration to the game: I have added line 55.

55 LET O=0

Without this line then the game can crash if you LOOK or SCORE in the first location as O hasn't been defined.
The game is completeable.

**Dang! that dwarf is annoying!!
AdventurePiperBooks.zip
(4.11 KiB) Downloaded 23 times


Lee.

User avatar
leenew
Posts: 3332
Joined: Wed Jul 04, 2012 3:27 pm
Location: Doncaster, Yorkshire

Re: Missing Adventure games

Postby leenew » Sat Aug 26, 2017 10:44 am

Here is another missing adventure, located by iamaran in the "Computer & Video Games Book Of Adventure" from Melbourne House.
Could someone have a go at OCRing it... [-o<
lc-p111.jpg

lc-p112.jpg

lc-p113.jpg

lc-p114.jpg

lc-p115.jpg

lc-p116.jpg

lc-p117.jpg


Thanks!

Lee.

User avatar
billcarr2005
Posts: 1057
Joined: Fri Sep 09, 2005 3:01 pm
Location: UK
Contact:

Re: Missing Adventure games

Postby billcarr2005 » Sat Aug 26, 2017 11:25 am

fuzzel wrote:I've just read the review of Hezarin in the November 1990 issue of the Micro User and found it came with the Last Days of Doom.
As the Last Days of Doom is available as a download I just wondered why Hezarin isn't ? Reading the review it sounds like a big miss.....


Just found this in my Last Days of Doom case, explains why I've not got it, at least!

HEZARIN.jpg
Hezarin explanation

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Sat Aug 26, 2017 5:52 pm

billcarr2005 wrote:Just found this in my Last Days of Doom case, explains why I've not got it, at least! ... HEZARIN.jpg

Interesting! Thanks.

Wonder if this adds weight to the theory that Hezarin was advertised for the Beeb but never actually released? (See various other threads on this forum for more details!) (Btw, an Electron version has already been found.)

:?:

User avatar
dv8
Posts: 46
Joined: Mon Jun 22, 2009 9:07 pm

Re: Missing Adventure games

Postby dv8 » Sun Aug 27, 2017 2:13 pm

leenew wrote:Here is another missing adventure, located by iamaran in the "Computer & Video Games Book Of Adventure" from Melbourne House.
Could someone have a go at OCRing it... [-o<

Here you go, OCRed and fixed.

...and, if anyone is interested, the solution:
(TAKE ROPE, PULL PAPER, GO DOOR, TAKE UMBRELLA, GO OUT, OPEN UMBRELLA, GO NORTH, CHOP TREE, PULL TREE, GO SOUTH, PULL TREE, GO EAST, PULL TREE, GO TREE, GO UP, LOOK AROUND, OPEN CUPBOARD, TAKE CROWN, GO UP, TIE ROPE, GO ROPE, SWING, JUMP, GO WEST, CLOSE UMBRELLA, GO COTTAGE, GO SOUTH, DROP CROWN, SCORE)
(drag the mouse over the hidden text to make it visible)
Attachments
cvg_adventure.zip
(3.63 KiB) Downloaded 13 times

User avatar
lurkio
Posts: 1153
Joined: Tue Apr 09, 2013 11:30 pm
Location: Doomawangara
Contact:

Re: Missing Adventure games

Postby lurkio » Sun Aug 27, 2017 5:21 pm

dv8 wrote:Here you go, OCRed and fixed.

Thank you!

=D> =D>


Return to “archive requests”

Who is online

Users browsing this forum: No registered users and 2 guests